/*
 * The MIT License (MIT)
 *
 * Copyright (c) 2025 Ziver Koc
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

// Documentation: https://jreleaser.org/guide/latest/examples/maven/maven-central.html#_gradle

nexusPublishing {
    repositories {
        sonatype {
            def repositoryUsername = project.hasProperty('mavenCentralUsername') ? mavenCentralUsername : "unknown"
            project.logger.info("Setting Maven Central Credentials: ${repositoryUsername}")

            username = repositoryUsername
            password = project.hasProperty('mavenCentralPassword') ? mavenCentralPassword : "unknown"
        }
    }
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java

            pom {
                name = 'Zutil'
                description = 'A library containing utility classes and code snippets.'
                url = 'https://github.com/Ziver/zutil'

                licenses {
                    license {
                        name = 'MIT License'
                        url = 'http://www.opensource.org/licenses/mit-license.php'
                    }
                }
                developers {
                    developer {
                        id = 'Ziver Koc'
                        name = 'dev@koc.se'
                    }
                }
                scm {
                    connection = 'scm:git:https://github.com/Ziver/zutil.git'
                    developerConnection = 'scm:git:https://repo.koc.se/zutil-java.git'
                    url = 'https://github.com/Ziver/zutil'
                }
            }
        }
    }
}

// Signing

signing {
    required { hasProperty("signing.secretKeyRingFile") }
    sign publishing.publications.maven
}

// Generate version.txt

ext.genOutputDir = file("${buildDir}/generated-resources")

task generateVersionTxt()  {
    ext.outputFile = file("${genOutputDir}/version.txt")
    outputs.file(outputFile)
    doLast {
        outputFile.text = """GroupId: ${project.group}
Name: ${project.name}
Version: ${version}
Build-time: ${java.time.LocalDateTime.now()}
"""
    }
}

sourceSets.main.output.dir genOutputDir, builtBy: generateVersionTxt