plugins {
    id 'java'
    id 'application'
}

/*
 * The MIT License (MIT)
 *
 * Copyright (c) 2025 Ziver Koc
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

// ------------------------------------
// Hal common configuration
// ------------------------------------

allprojects {
    repositories {
        mavenLocal()
        mavenCentral()
    }
}

subprojects { 
    apply plugin: 'java-library'

    dependencies {
        //implementation 'se.koc:zutil:1.0.314'
        implementation 'se.koc:zutil:1.0.0-SNAPSHOT'

        testImplementation 'junit:junit:4.12'
        testImplementation 'org.hamcrest:hamcrest-core:2.2'
    }

    sourceSets {
        main {
            java {
                srcDirs 'src'
            }
            // We do not want the resource folder to be included in the jar file
            //resources {
            //    srcDir 'resource'
            //}
        }
        test {
            java {
                srcDirs 'test'
            }
        }
    }
}

// ------------------------------------
// Hal general configuration
// ------------------------------------

dependencies {
    project.subprojects.each { subProject ->
        runtimeOnly subProject
    }
}

distributions {
    distTar.enabled = false
    distZip.enabled = false

    main {
        contents {
            from 'hal.conf.example'
            from 'logging.properties'

            from sourceSets.main.output.resourcesDir
        }
    }
}

task copyRecources(type: Copy) {
    doFirst{
        System.out.println("Copying resource files...")
    }

    project.subprojects.each { subProject ->
        from "${subProject.projectDir}/resources"
    }

    into(sourceSets.main.output.resourcesDir)
}

jar.dependsOn(copyRecources)
copyRecources.mustRunAfter(processResources)

application {
    mainClass = 'se.hal.HalServer'
}